#debug "\nCreation de la Piece ........\n"
#declare Piece_Murs=
union{
   #declare Hauteur = 0;
   #while (Hauteur < Y_Fin)
   #declare X_Position = 0;
   #declare Z_Position = 0;
      object{H_Parpaing_Debut  translate <X_Position,Hauteur,Z_Position>}
   #declare X_Position = X_Position - Lon_Parpaing - Lon_Joint - E_Papier - E_Platre;
   #declare Compteur = 1;
   #while (Compteur < 8)
      object{H_Parpaing_Milieu translate <X_Position,Hauteur,Z_Position>}
      object{H_Joint           translate <X_Position,Hauteur,Z_Position>}
      #declare X_Position = X_Position - Lon_Parpaing - Lon_Joint;
      #declare Compteur = Compteur + 1;
   #end

   #declare X_Position_X = X_Position;
   #declare Z_Position_Z = Z_Position;
   #declare Z_Position = Z_Position - 2 * Lar_Parpaing + Lon_Joint;
   #declare X_Position = X_Position - Lon_Joint + 2 * Lar_Parpaing;
   #declare Compteur = 1;
   #while (Compteur < 9)
      object{V_Parpaing_Milieu translate <X_Position,Hauteur,Z_Position>}
      #if (Compteur = 1)
      object{H_Joint           translate <X_Position_X,Hauteur,Z_Position_Z>}
      #else
      object{V_Joint           translate <X_Position,Hauteur,Z_Position>}
      #end
      #declare Z_Position = Z_Position - Lon_Parpaing - Lon_Joint;
      #declare Compteur = Compteur + 1;
   #end
      object{V12_Parpaing      translate <X_Position,Hauteur,Z_Position>}
      object{V_Joint           translate <X_Position,Hauteur,Z_Position>}

   #declare Hauteur = Hauteur + Hau_Joint + Hau_Parpaing;
   #declare Z_Position = Z_Position + Lon_Parpaing / 2 + 2 * Lon_Joint;
      object{V_Parpaing_Debut  translate <X_Position,Hauteur,Z_Position>}

   #declare Z_Position = Z_Position + Lon_Parpaing + Lon_Joint;
   #declare Compteur = 1;
   #while (Compteur < 8)
      object{V_Parpaing_Milieu translate <X_Position,Hauteur,Z_Position>}
      object{V_Joint translate <X_Position,Hauteur,Z_Position - Lon_Parpaing - Lon_Joint>}
      #declare Z_Position = Z_Position + Lon_Parpaing + Lon_Joint;
      #declare Compteur = Compteur + 1;
   #end

   #declare X_Position_X = X_Position;
   #declare Z_Position_Z = Z_Position;
   #declare Compteur = 1;
   #while (Compteur < 9)
      object{H_Parpaing_Milieu translate <X_Position,Hauteur,Z_Position>}
      #if (Compteur = 1)
      object{V_Joint translate <X_Position_X,Hauteur,Z_Position_Z - Lon_Parpaing - Lon_Joint>}
      #else
      object{H_Joint  translate <X_Position - Lon_Parpaing - Lon_Joint,Hauteur,Z_Position>}
      #end
      #declare X_Position = X_Position + Lon_Parpaing + Lon_Joint;
      #declare Compteur = Compteur + 1;
   #end
      object{H12_Parpaing      translate <X_Position - Lon_Parpaing / 2 - Lon_Joint - E_Papier - E_Platre,Hauteur,Z_Position>}
      object{H_Joint    translate <X_Position - Lon_Parpaing - Lon_Joint,Hauteur,Z_Position>}
  #declare Hauteur = Hauteur + Hau_Joint + Hau_Parpaing;
  #end

translate<X_Fin - Lon_Parpaing - X_Debut,Y_Debut,Z_Fin + E_Papier + E_Platre - Z_Debut>
     }
