#debug "\nCreation du Gueridon ........\n"
#declare X_Position    = 250;
#declare Z_Position    = 850;

#declare Pieds =
difference{
  union{
     cylinder{<9,35,-3>,<9,35,3> 22 scale<0.9,1.1,1>}
     cylinder{<30.35,0,-3>,<30.35,0,3> 4 scale<1.5,0.98,1>}
     difference{
        box{<-0.01,-0.01,-3.01>,<46.01,37,3.01>}
        cylinder{<38,16.5,-3>,<38,16.5,3> 15 scale<1.201,2.601,1.01>}
               }
       }
  union{
     cylinder{<0,0,0>,<0,100,0>,Dia_Colonne * 1.11}
     box{<-100,-100,-100>,<0,100,100>}
     box{<-100,63,-100>,<100,100,100>}
     box{<-100,-100,-100>,<100,0,100>}
     box{<0,-100,-100>,<10,33,100>}
     cylinder{<18,-3,-3.011>,<18,-3,3.011> 18   scale<0.8,2.2,1> rotate 15 * z}
       }
texture{Tex_Gueridon}
translate -0.4*x
          }


#declare Corps =
union{
   cylinder{<0,0,0>,<0,33,0>,Dia_Colonne texture{Tex_Gueridon}}
   sor{14 <Dia_Colonne,33>,<Dia_Colonne,33>,<Dia_Colonne * 1.2,36>,<Dia_Colonne ,39>,<Dia_Colonne * 1.2,42>,<Dia_Colonne,45>,<Dia_Colonne * 1.275,55>,<Dia_Colonne,96>,<Dia_Colonne * 1.2,99>,<Dia_Colonne ,102>,<Dia_Colonne * 1.2,105>,<Dia_Colonne,108>,<Dia_Colonne,Hau_Colonne>,<Dia_Colonne,Hau_Colonne> sturm texture{Tex_Gueridon}}
     }

#declare Plateau =
difference{
   union{
      torus{Dia_Plateau,E_Plateau / 2 translate <0,0,0> texture{Tex_Gueridon}}
      cylinder{<0,0,0>,<0, E_Plateau, 0>,Dia_Plateau texture{Tex_Gueridon}}
        }
   union{
      box{<-Dia_Plateau * 2,0.01,-Dia_Plateau * 2>,<Dia_Plateau * 2,- E_Plateau,Dia_Plateau * 2> texture{Tex_Gueridon}}
      torus{Dia_Plateau,E_Plateau / 2.5 translate <0,E_Plateau + 0.1,0> texture{Tex_Gueridon}}
        }
          }



#declare Gueridon =
union{
   object{Pieds rotate  30 * y translate<X_Position,0,Z_Position>}
   object{Pieds rotate 150 * y translate<X_Position,0,Z_Position>}
   object{Pieds rotate 270 * y translate<X_Position,0,Z_Position>}
   object{Corps translate<X_Position,Bas_Colonne,Z_Position>}
   object{Plateau translate<X_Position,Haut_Plateau,Z_Position>}
     }

